SUPPLEMENTARY MATERIALS TO

Chi-square Difference Tests for Comparing Nested Models:

An Evaluation with Non-normal Data

Example and Mplus Code for Computing Chi-Square Difference Tests

In the following example, we describe how to compute chi-square difference tests using Mplus software. Mplus syntax is included in the example so that applied researchers may utilize it in their own research.

The data set for the example (“pc.dat”) contains four indicators measuring a unidimensional latent factor at two time-points. The total number of observed variables is thus eight. Sample size is 500.

The baseline model (M1) in the example is the *configural invariance* model with the factor correlation and all factor loadings at each time-point freely estimated. The restricted model (M0) is the *weak invariance* model, which introduces equality constraints on all four factor loadings between the two time-points. The number of additional constraints in the model M0 is thus four.

We include Mplus code for computing the uncorrected difference test - D, Satorra-Bentler “original” difference test (2001) in concert with MLM - DSB1MLM, Satorra-Bentler “strictly positive” difference test (2010) in concert with MLM - DSB10MLM, and Asparouhov-Muthén chi-square difference test (2010) - DMLMV. For options involving choice MLR, the code for MLM can be used simply by replacing the estimator in the analysis command.

We also provide results for all six options discussed in the paper.

Computing the Uncorrected Difference Test

*Step 1:* Estimating configural invariance model () with ML.

TITLE: CONFIGURAL INVARIANCE (MODEL M1) WITH ML

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = ML;

MODEL:

!factor loadings freely estimated at both time points

f1 by pc1\_1-pc1\_4\*;

f2 by pc2\_1-pc2\_4\*;

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

Chi-square test statistic () and degrees of freedom () are provided in the output.

*Step 2:* Estimating weak invariance model () with ML.

TITLE: WEAK INVARIANCE (MODEL M0) WITH ML

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = ML;

MODEL:

!factor loadings are set to equality between time points

f1 by pc1\_1-pc1\_4\* (1-4);

f2 by pc2\_1-pc2\_4\* (1-4);

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

Chi-square test statistic () and degrees of freedom () are provided in the output.

*Step 3:* The uncorrected chi-square difference statistic (D) is obtained with the Equation in (2). Number of degrees of freedom for the difference test is .

Computing Satorra-Bentler “Original” Difference Test (2001) with Choice MLM (or MLR)

*Step 1:* Estimating configural invariance model () with MLM.

TITLE: CONFIGURAL INVARIANCE (MODEL M1) WITH MLM

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = MLM;

MODEL:

!factor loadings freely estimated at both time points

f1 by pc1\_1-pc1\_4\*;

f2 by pc2\_1-pc2\_4\*;

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

Robust chi-square test statistic (), degrees of freedom (), and scaling correction factor () are provided in the output.

*Step 2:* Estimating weak invariance model () with MLM.

TITLE: WEAK INVARIANCE (MODEL M0) WITH MLM

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = MLM;

MODEL:

!factor loadings are set to equality between time points

f1 by pc1\_1-pc1\_4\* (1-4);

f2 by pc2\_1-pc2\_4\* (1-4);

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

Robust chi-square test statistic (), degrees of freedom (), and scaling correction factor () are provided in the output.

*Step 3*: The two scaling correction factors ( and ) and two degrees of freedom ( and ) are introduced into Equation in (3) to obtain the scaling correction for the difference ().

*Step 4:* The uncorrected chi-square difference statistic (D) computed earlier is divided by the scaling correction  to obtain the corrected chi-square difference statistic (DSB1MLM). Number of degrees of freedom for the difference test is .

Computing Satorra-Bentler “Strictly Positive” Difference Test (2010) with Choice MLM (or MLR)

*Step 1:* Estimating weak invariance model () with MLM and requesting syntax for model  in the output.

TITLE: WEAK INVARIANCE (MODEL M0) WITH MLM REQUESTING SVALUES

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = MLM;

MODEL:

!factor loadings are set to equality between time points

f1 by pc1\_1-pc1\_4\* (1-4);

f2 by pc2\_1-pc2\_4\* (1-4);

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

!generating syntax for model M\* in the output

OUTPUT: SVALUES;

Robust chi-square test statistic (), degrees of freedom (), scaling correction factor (), and syntax for model  are provided in the output (under “MODEL COMMAND WITH FINAL ESTIMATES USED AS STARTING VALUES”).

*Step 2:* Estimating configural invariance model .

TITLE: CONFIGURAL INVARIANCE MODEL M\*

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = MLM;

!to set the number of iterations to 0

CONVERGENCE=100000000

MODEL:

!introducing syntax for model M\*

!obtained from the output of M1 run in step 1

f1 BY pc1\_1\*0.57830;

f1 BY pc1\_2\*0.56133;

f1 BY pc1\_3\*0.62387;

f1 BY pc1\_4\*0.48925;

f2 BY pc2\_1\*0.57830;

f2 BY pc2\_2\*0.56133;

f2 BY pc2\_3\*0.62387;

f2 BY pc2\_4\*0.48925;

pc1\_1 WITH pc2\_1\*0.10261;

pc1\_2 WITH pc2\_2\*0.03403;

pc1\_3 WITH pc2\_3\*0.15778;

pc1\_4 WITH pc2\_4\*0.17586;

f2 WITH f1\*0.84084;

[ pc1\_1\*3.20400 ];

[ pc1\_2\*3.61400 ];

[ pc1\_3\*3.44600 ];

[ pc1\_4\*3.51400 ];

[ pc2\_1\*3.31400 ];

[ pc2\_2\*3.72400 ];

[ pc2\_3\*3.50400 ];

[ pc2\_4\*3.56800 ];

pc1\_1\*0.43837;

pc1\_2\*0.28083;

pc1\_3\*0.38353;

pc1\_4\*0.46765;

pc2\_1\*0.35235;

pc2\_2\*0.23927;

pc2\_3\*0.34973;

pc2\_4\*0.48929;

f1@1;

f2@1;

!to confirm that the number of iterations was 0

OUTPUT: TECH5;

The scaling correction factor  and degrees of freedom () are provided in the output.

*Step 3*: The two scaling corrections,  and , and corresponding degrees of freedom ( and ) are introduced into Equation in (4) to obtain the scaling correction .

*Step 3:* The uncorrected chi-square difference (D) is divided by the scaling correction  to obtain the corrected chi-square difference statistic DSB10MLM. Degrees of freedom for the difference test are .

Computing Asparouhov-Muthén (2010) Chi-Square Difference Test with Choice MLMV

*Step 1:* Estimating configural invariance model () with MLMV and saving data for the difference test.

TITLE: CONFIGURAL INVARIANCE (MODEL M1) WITH MLMV

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = MLMV;

MODEL:

!factor loadings freely estimated at both time points

f1 by pc1\_1-pc1\_4\*;

f2 by pc2\_1-pc2\_4\*;

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

!saving data for the difference test

SAVEDATA: DIFFTEST IS diffmlmv.dat;

*Step 2:* Estimating weak invariance model () with MLMV using the saved data from Step 1.

TITLE: WEAK INVARIANCE (MODEL M0) WITH MLMV AND DIFFTEST

DATA: FILE IS 'pc.dat';

VARIABLE: NAMES ARE

!four factor indicators at time 1

pc1\_1-pc1\_4

!four factor indicators at time 2

pc2\_1-pc2\_4;

ANALYSIS: ESTIMATOR = MLMV;

DIFFTEST IS diffmlmv.dat;

MODEL:

!factor loadings are set to equality between time points

f1 by pc1\_1-pc1\_4\* (1-4);

f2 by pc2\_1-pc2\_4\* (1-4);

!factor correlation freely estimated

f2 with f1;

!both factor variances set to 1

f1-f2@1;

!residual correlations between time points estimated

pc1\_1 with pc2\_1;

pc1\_2 with pc2\_2;

pc1\_3 with pc2\_3;

pc1\_4 with pc2\_4;

The Asparouhov-Muthén (2010) chi-square difference statistic DMLMV, degrees of freedom, and the corresponding p-value are available in the output under “Chi-Square Test for Difference Testing”.

Results

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
|  | Configural invariance(*df* = 15) |  | Weak invariance(*df* = 19) |  | Difference Test(*df* = 4) |
| Choice |  | p-value |  |  | p-value |  | Correction |  | p-value |
| ML | 28.069 | .0211 |  | 33.373 | .0218 |  | D (uncorrected difference test) | 5.304 | .2575 |
| MLM | 21.732 | .1150 |  | 26.938 | .1061 |  | DSB1 (Satorra & Bentler, 2001) | 5.094 | .2778 |
| 21.732 | .1150 |  | 26.938 | .1061 |  | DSB10 ( Satorra & Bentler, 2010) | 4.917 | .2960 |
| MLR | 21.979 | .1084 |  | 26.983 | .1050 |  | DSB1 (Satorra & Bentler, 2001) | 4.885 | .2993 |
| 21.979 | .1084 |  | 26.983 | .1050 |  | DSB10 ( Satorra & Bentler, 2010) | 4.832 | .3050 |
| MLMV | 21.004 | .1367 |  | 26.099 | .1275 |  | DMLMV (Asparouhov & Muthén, 2010) | 4.976 | .2898 |
| *Note*: n = 500; *df* = degrees of freedom; = chi-square; = chi-square difference. |